AFTER INSERT Triggers in SQL Server

The SQL Server AFTER INSERT Triggers will fire after the completion of the Insert operation. In this article, we will show you, How to write the After INSERT Triggers in SQL Server with an example. For this demonstration, We are going to use the below-shown tables.

As you can see from the below screenshot that our Employee table is Empty, and our task is to create AFTER INSERT TRIGGER on this Employee table. And by using this trigger, we want to Insert the records into Employee Table Audit, along with the audit information

TIP: You can refer AFTER UPDATE article to understand the AFTER UPDATE Trigger and AFTER DELETE article for the AFTER DELETE Trigger.

and our Employee Table Audit is also empty

NOTE: SQL After Insert Triggers are not Supported on Views

After INSERT Triggers in SQL Server Example

In this example, we will show you, How to create an After Insert Triggers in SQL Server. Next, we will create a trigger on the Employee table using the CREATE TRIGGER Statement.

Remember, After Insert trigger will fire after the completion of Insert operation on Employee table. Once it completes inserting into the Employee table, it will start inserting into Employee audit table. If it fails to insert into the Employee table then it won’t insert into the Audit table.

-- Example for After INSERT Triggers in SQL Server
USE [SQL Tutorial]
GO
CREATE TRIGGER AfterINSERTTrigger on [EmployeeTable]
FOR INSERT 
AS DECLARE @EmpID INT,
	   @EmpName VARCHAR(50),
	   @EmpEducation VARCHAR(50),
	   @EmpOccupation VARCHAR(50),
	   @EmpYearlyIncome DECIMAL (10, 2), 
	   @EmpSales DECIMAL (10, 2); 

SELECT @EmpID = ins.ID FROM INSERTED ins;
SELECT @EmpName = ins.Name FROM INSERTED ins;
SELECT @EmpEducation = ins.Education FROM INSERTED ins;
SELECT @EmpOccupation = ins.Occupation FROM INSERTED ins;
SELECT @EmpYearlyIncome = ins.YearlyIncome FROM INSERTED ins;
SELECT @EmpSales = ins.Sales FROM INSERTED ins;

INSERT INTO [EmployeeTableAudit]( 
       [ID]
      ,[Name]
      ,[Education]
      ,[Occupation]
      ,[YearlyIncome]
      ,[Sales]
      ,[ServerName]
      ,[ServerInstanceName]
      ,[Insert Time])
VALUES (@EmpID,
	@EmpName,
	@EmpEducation,
	@EmpOccupation,
	@EmpYearlyIncome,
	@EmpSales,
	CAST( SERVERPROPERTY('MachineName') AS VARCHAR(50)), 
	CAST( SERVERPROPERTY('ServerName') AS VARCHAR(50)), 
	GETDATE()
	);
PRINT 'We Successfully Fired the AFTER INSERT Triggers in SQL Server.'
GO

OUTPUT

ANALYSIS

First, we used the DECLARE Statement to declare the required variables

DECLARE @EmpID INT,
	@EmpName VARCHAR(50),
	@EmpEducation VARCHAR(50),
	@EmpOccupation VARCHAR(50),
	@EmpYearlyIncome DECIMAL (10, 2), 
	@EmpSales DECIMAL (10, 2);

Next, we used the SELECT Statement to select the records. Following statements will select one records from inserted values.

SELECT @EmpID = ins.ID FROM INSERTED ins;
SELECT @EmpName = ins.Name FROM INSERTED ins;
SELECT @EmpEducation = ins.Education FROM INSERTED ins;
SELECT @EmpOccupation = ins.Occupation FROM INSERTED ins;
SELECT @EmpYearlyIncome = ins.YearlyIncome FROM INSERTED ins;
SELECT @EmpSales = ins.Sales FROM INSERTED ins;

Next, we used the INSERT Statement to insert the selected values into the Employee Audit Table. Here, following statements will return the Machine Name and the server name. This information might be helpful for the audit

SERVERPROPERTY('MachineName'), 
SERVERPROPERTY('ServerName')

Let me show you the newly created trigger by opening the Object Explorer -> Go to the SQL Tutorial Database -> Go and expand the Employee Table -> and then expand the Triggers Folder

For the demonstration purpose we are inserting 5 random records into the Employee table, to check whether the After insert Trigger is triggered or not.

T-SQL CODE

USE [SQL Tutorial]
GO
INSERT INTO [EmployeeTable] (
		[Name]
	       ,[Education]
	       ,[Occupation]
	       ,[YearlyIncome]
	       ,[Sales]
	     )
VALUES ('Tutorial Gateway', 'Masters', 'Admin', 150000, 900)
      ,('Imran Khan', 'Bachelors', 'Skilled Professional', 69000, 100)
      ,('Doe Lara', 'Bachelors', 'Management', 85000, 60)
      ,('Ramesh Kumar', 'High School', 'Professional', 45000, 630)
      ,('John Ruiz', 'Partial High School', 'Clerical', 40000, 220)

OUTPUT

From the above screenshot, you can see that our trigger is triggered, and also inserted one record into the Audit Table. Please use the following SQL Query to check the inserted records in the Employee table

USE [SQL Tutorial]
GO
SELECT [ID]
      ,[Name]
      ,[Education]
      ,[Occupation]
      ,[YearlyIncome]
      ,[Sales]
  FROM [EmployeeTable]

OUTPUT

Next, check the records in the Employee table Audit using the following query.

USE [SQL Tutorial]
GO

SELECT [ID]
      ,[Name]
      ,[Education]
      ,[Occupation]
      ,[YearlyIncome]
      ,[Sales]
      ,[ServerName]
      ,[ServerInstanceName]
      ,[Insert Time]
  FROM [EmployeeTableAudit]

OUTPUT

From the above screenshot, you can see that our Audit Table is returning a single record. This is because, In our Trigger definition, we are selecting only one record for each insert.

After INSERT Triggers in SQL Server Example 2

In this example, we will show you, How to insert all the records into the audit table (triggered table) using the After Insert Triggers in SQL Server. And here, we will modify the trigger that we created in our previous example.

-- Second Example for After INSERT Triggers in SQL Server
USE [SQL Tutorial]
GO
CREATE TRIGGER AfterINSERTTriggerExample on [EmployeeTable]
FOR INSERT 
AS 
INSERT INTO [EmployeeTableAudit]( 
       [ID]
      ,[Name]
      ,[Education]
      ,[Occupation]
      ,[YearlyIncome]
      ,[Sales]
      ,[ServerName]
      ,[ServerInstanceName]
      ,[Insert Time])
SELECT  ID,
	    Name,
	    Education,
	    Occupation,
	    YearlyIncome,
	    Sales,
	    CAST( SERVERPROPERTY('MachineName') AS VARCHAR(50)), 
	    CAST( SERVERPROPERTY('ServerName') AS VARCHAR(50)), 
	    GETDATE()
FROM INSERTED;
PRINT 'We Successfully Fired Our Second AFTER INSERT Triggers in SQL Server.'
GO

From the above code snippet, you can see that, we are using the INSERT INTO SELECT Statement to select all the records that are inserting into Employee table, and then we are inserting those records into the Audit table.

Next, let me insert some random records into the employee table

USE [SQL Tutorial]
GO
INSERT INTO [EmployeeTable] (
		    [Name]
		   ,[Education]
		   ,[Occupation]
		   ,[YearlyIncome]
		   ,[Sales]
	     )
VALUES ('Tutorial Gateway', 'Masters', 'Admin', 150000, 900)
      ,('Doe Lara', 'Bachelors', 'Management', 85000, 60)
      ,('Ramesh Kumar', 'High School', 'Professional', 45000, 630)
      ,('John Ruiz', 'Partial High School', 'Clerical', 40000, 220)
      ,('Imran Khan', 'Bachelors', 'Skilled Professional', 69000, 100)

OUTPUT

From the above screenshot, you can see that our after insert trigger has fired, and also inserted all the records into the audit table. Let us see the Employee table

Next, check with the Employee Audit table.

From the above screenshot, you can see that the trigger has inserted all the records.